@ECHO OFF

rem RAR.exeのフルパスを入力↓
SET RAR="D:\Program Files\WinRAR\RAR.exe"

rem 圧縮出力先を入力 (必ず最後尾に\ / ファイル名を使用したい場合は \ の後に記入)↓
rem (ファイル名を指定したい場合は \ の後に記入 / 例 r:\test)↓
SET ARC="R:\"

rem 圧縮ファイル名に作成時刻を使用 / 使用しない場合は""にする)↓
rem これを無効にした場合は圧縮出力先にてファイル名を入力しないと無名の書庫が出来ます。
SET FILETIME="-agYYMMDD-HHMM"

rem 圧縮時の容量分割 (-vの後に記入 例:10メガ -v10M / 使用しない場合は""にする)↓
SET Byt="-v19M"

rem 圧縮から除外するファイル (-xの後に記入 / 使用しない場合は""にする)↓
SET NoARC="-xThumbs.d? -x*.bak"

rem 圧縮時に使用するPassword (-hpの後にPass / 使用しない場合は""にする)↓
rem ひらがな、カタカナ、漢字、英数字も可能、ただ空白は含めないように
SET PASS1="-hp5963"

rem 解凍出力先を入力 (必ず最後尾に\)↓
SET OUT="R:\"

rem 解凍時に使用するPassword (-pの後にPass / 使用しない場合は""にする)↓
rem ひらがな、カタカナ、漢字、英数字も可能、ただ空白は含めないように
SET PASS2="-p5963"

rem 解凍時、書庫毎にフォルダを作成  (使用しない場合は""にする)↓
SET newfolder="-AD"

rem ※1 圧縮時、空のフォルダを格納する場合は [-ED] を削除
rem ※2 この.batはフォルダ1個をドラッグして圧縮する事を主として作られていますので
rem 　　複数のフォルダやフォルダをドラッグすると圧縮開始時間により
rem 　　複数の圧縮書庫ファイルができあがる事があります。
rem 　　作成時刻を使用不可にしたり各自工夫を。
rem ※3 WinRARはシェアウェアです。
rem 　　有り難い事に無料使用期限が過ぎての使用も可能ですが
rem 　　継続して利用する場合はご購入をお勧め致します。
rem 　　また、このバッチファイルはWinRARの作者様方とは何の関連もありませんので
rem 　　使用方法等を問い合わせないようお願い致します。

cls
echo.
echo ** 解凍 **
echo 作業場所 %OUT% 
echo.
echo [1] 全て解凍
echo [2] 危険拡張子を除外して解凍
echo [3] 画像のみ解凍
echo [4] 文章のみ解凍
echo.
echo ** 圧縮 **
echo 作業場所 %ARC% 
echo.
echo [5] 無圧縮＋RR3＋分割容量%Byt%
echo [6] 最高圧縮＋RR3＋分割容量%Byt%
echo.
echo [9] 処理中止
echo.
choice /c:1234569
IF ERRORLEVEL 7 GOTO END1
IF ERRORLEVEL 6 GOTO ARC2
IF ERRORLEVEL 5 GOTO ARC1
IF ERRORLEVEL 4 GOTO OUT4
IF ERRORLEVEL 3 GOTO OUT3
IF ERRORLEVEL 2 GOTO OUT2
IF ERRORLEVEL 1 GOTO OUT1

:OUT1
rem 全部
if ""%1""=="""" goto END1
%RAR% x -xThumbs.d? %newfolder% %PASS2% %1 %OUT%
shift
goto OUT1

:OUT2
rem 危険拡張子を除外
if ""%1""=="""" goto END1
%RAR% x -x*.exe -x*.scr -x*.vbs -x*.bat -x*.com -x*.pif -x*.cmd -x*.lnk -xThumbs.d? %newfolder% %PASS2% %1 %OUT%
shift
goto OUT2

:OUT3
rem 画像のみ
if ""%1""=="""" goto END1
%RAR% x -n*.bmp -n*.png -n*.jpg -n*.jpeg -n*.gif %newfolder% %PASS2% %1 %OUT%
shift
goto OUT3

:OUT4
rem 文章のみ
if ""%1""=="""" goto END1
%RAR% x -n*.txt -n*.htm -n*.html %newfolder% %PASS2% %1 %OUT%
shift
goto OUT4

:ARC1
rem 無圧縮＋RR3＋19M分割
if ""%1""=="""" goto END1
%RAR% a -rr3 -ep1 -m0 -MS -ED %Byt% %FILETIME% "%NoARC%" %PASS1% %ARC% %1
shift
goto ARC1

:ARC2
rem 最高圧縮＋RR3＋19M分割
if ""%1""=="""" goto END1
%RAR% a -rr3 -ep1 -m5 -MS -ED %Byt% %FILETIME% "%NoARC%" %PASS1% %ARC% %1
shift
goto ARC2

:END1